Với người dùng win, vấn nạn auturun chưa bao giờ là cũ.
Thủ thuật này cần sử dụng 2 phần mềm(thực ra là 2 file *.bat) mình đã lấy trong cd cứu hộ máy tính mới nhất: hiren boot 14.1 chính hãng và việt hóa cho mọi người dễ dùng.
Mọi người cũng hoàn toàn có thể sửa lại nó.

Trước tiên là: vô hiệu hóa/kịch hoạt tính năng autorun của win:
Mã:
Code:
@echo off 
Set _reg="HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\IniFileMapping\Autorun.inf" 
REG QUERY %_reg%>NUL 
if errorlevel 1 goto d 
echo Kich hoat tinh nang USB Autorun 
echo. 
echo Nhan phim bat ki de xac nhan (hoac dong cua so nay de huy bo) 
pause>nul 
REG DELETE %_reg% /f 
goto x 
:d 
cls 
echo vo hieu hoa USB Autorun de bao ve may tinh tu virut trong usb 
echo. 
echo Nhan phim bat ki de xac nhan (hoac dong cua so nay de huy bo) 
pause>nul 
REG ADD %_reg% /ve /d "@SYS:DoesNotExist" /f 
:x 
echo. 
echo Nhan phim bat ki de thoat 
pause>nul
cách tạo file bat:
+mở phần mềm soạn thảo văn bản(mình dùng notepad là tốt nhất)
+copy đoạn code trên vào
+save file
+chọn thư mục cần lưu
+nhập tên file dạng: ten_ban_nuon_dat.*bat
+ở phần Save as type chọn "All type"
+ở phần encoding chọn ANSI
+-> Save


Cách dùng rất đơn giản:
+nếu tính năng autorun đang được sử dụng-> khi chạy phần mềm nó sẽ tắt đi


+nếu tính năng auturun đang bị tắt-> khi chạy phần mềm nó sẽ bật lên


(giống như kiểu nếu là 0 thì sửa thành 1 và nếu là 1 thì sửa thành 0)
Chúng ta chỉ cần click chạy chương trình và ok. là xong



Phần mềm thứ hai để tạo autorun giả cho các ổ đĩa để auturun thật không thể xâm nhập vào được
Code:
@echo off
echo chuong trinh nay se tao ra tep tin AUTORUN.INF gia de bao ve may tinh
echo.
echo  1. tao auturun gia
echo  2. xoa auturun gia
echo  3. thoat
echo.
set /p twk=Moi chon chuc nang : 
if "%twk%"=="1" goto d
if "%twk%"=="2" goto d
exit
:d
set /p usbdr=Bay gio hay nhap ten o dia(VD: E) : 
if not exist %usbdr%:\nul echo Khong co o dia %usbdr%:\
if not exist %usbdr%:\nul goto d
if "%twk%"=="1" goto m
if "%twk%"=="2" goto r
exit
:m
if exist %usbdr%:\Recycler\nul rmdir /s /q \\.\\%usbdr%:\Recycler
if exist %usbdr%:\Recycler del /f /q /a %usbdr%:\Recycler
echo Hiren's BootCD> %usbdr%:\Recycler
attrib %usbdr%:\Recycler +r +s +h

if exist %usbdr%:\$Recycle.Bin\nul rmdir /s /q \\.\\%usbdr%:\$Recycle.Bin
if exist %usbdr%:\$Recycle.Bin del /f /q /a %usbdr%:\$Recycle.Bin
echo Hiren's BootCD> %usbdr%:\$Recycle.Bin
attrib %usbdr%:\$Recycle.Bin +r +s +h

if exist %usbdr%:\Recycled\nul rmdir /s /q \\.\\%usbdr%:\Recycled
if exist %usbdr%:\Recycled del /f /q /a %usbdr%:\Recycled
echo Hiren's BootCD> %usbdr%:\Recycled
attrib %usbdr%:\Recycled +r +s +h

if exist %usbdr%:\Autorun.inf del /f /q /a %usbdr%:\Autorun.inf
mkdir \\.\\%usbdr%:\Autorun.inf\nul.Hiren'sBootCD
attrib %usbdr%:\Autorun.inf +s +h
echo Thu muc %usbdr%:\AUTORUN.INF vaFile RECYCLER da duoc tao ra
goto x
:r
rmdir /s /q \\.\\%usbdr%:\Autorun.inf
del /f /q /a %usbdr%:\Recycled
del /f /q /a %usbdr%:\Recycler
del /f /q /a %usbdr%:\$Recycle.Bin
echo Thu muc %usbdr%:\AUTORUN.INF va RECYCLER Files da duoc xoa
:x
set usbdr=
echo.
echo Nhan phim bat ki de thoat
pause>nul


cách tạo file bat:
+mở phần mềm soạn thảo văn bản(mình dùng notepad là tốt nhất)
+copy đoạn code trên vào
+save file
+chọn thư mục cần lưu
+nhập tên file dạng: ten_ban_nuon_dat.*bat
+ở phần Save as type chọn "All type"
+ở phần encoding chọn ANSI
+-> Save


Cách dùng:
khi chạy có 3 chức năng:
1. tạo auturun giả
2. Xóa auturun giả
3. thoát

+ Tạo auturun giả:
Chọn 1 và nhập ổ đĩa cần tạ ok. Nếu không có ổ đĩa đó nó sẽ báo không có ổ đĩa



+ Xóa auturun giả-chỉ dùng cho các ổ đã tạo auturun giả
chọn 2 -> nhập nhập ổ đĩa cần xóa-> ok. Nếu không có ổ đĩa đó nó sẽ báo không có ổ đĩa



Hãy nói lời chia tay với virut auturun thôi nào